Trading on the Edge/Trading On The Edge - CD-ROM Toolkit (Wayzata Technology)(2031)(1994).bin/pc/mac_file/vendor_d/neuralwa/nw2v50/grnn.ind

File List | 1993-08-23 | 4KB | 240 lines

inst4.1
!****************************************************************
!*                                *
!*    General Regresion Neural Network Builder        *
!*                                *
!****************************************************************
!
?&In    1
>bge    ChkProto
@Err    "General Regression Neural Networks MUST have at least one input PE"
:ChkProto
?&Prt    1
>bge    CheckOut
@Err    "General Regression Neural Networks MUST have at least one output PE"
:CheckOut
?&Out    1
>bge    OutOK
@Err    "General Regression Neural Networks  MUST have at least one pattern unit"
:OutOK

!    *** Load the Control Strategy and schedules ***
@LdCS    "grnn"

=netn "Untitled"
=DLnF    0            !learn  re-display off
=DRcF    0            !recall re-display off

!    *** Build the Input Layer ***

@LLdf                !load default layer to menu area
=LDln    "In"            !layer name
=Lpes    &In            !copy # of input PEs from menu
=x    100            !place to put layer on screen
=y     40
@LDfW                !Default # weight fields
@LAdd                !add the input layer

!    *** Build a Projection Layer if projection summation  ***

?RBFS    2            !Projection summation?
>bne    ProjL1            !No

#Incl   "proj_lyr.iif"

:ProjL1
!
=n6    LayN            !previous layer
!
! Build Pattern layer
!
@LLdf                !start with default layer again
=LDln    "Pattern"        !layer name
=Lpes    &Prt            !Number of PEs
! Summation function
?RBFS    1            !City-Block?
>bne    Sum1
=Lsum    "City-Block"
>br    SumEnd
:Sum1
?RBFS    2            !Projection?
>bne    Sum2
=Lsum    "Sum"            !standard summation
>br    SumEnd
:Sum2                !Default
=Lsum    "Euclidean"
:SumEnd

=Ltrn    "Linear"
=Llrn    "K-Means"
=Lerf    "standard"
=Ltrn    "GRNN"
=Lcmp    "Select"
! Set up schedule
@NLRS    "grnn"
=lcta    99999
! Learning Rate
=ArrX    1
=lcft    "No Recode"
=lcfa    0.0
! Radius of Influence
=ArrX    2
=lcft    "Cluster Radius"
=lcfa    RInf
! Sigma Scale
=ArrX    5
=rcfa    SgSc
=rcft    "Sigma Scale"
! Sigma Gain
=ArrX    6
=rcfa    SgEx
=rcft    "Sigma Exponent"
@SLRS
=ArrX    0
=Llrs    "grnn"

=LInH    0.1
=LInL    -0.1
+y    60            !up higher on display
@LDfW                !Default # weight fields
@LAdd

! Connect input layer to pattern layer

=cnwt    1.0
=cnty    WVar            !Variable
=cnsc    WRel            !Relative
=SPEl    LayN            !destination layer
@SlPE                !select as destination
=NPEl    n6            !source layer
@NrPE                !select as source
@LCFl                !full connections

=n6    LayN            !pattern layer

! Build Summation layer. First PE in summation layer
! is the divisor.
@LLdf                !start with default layer again
=LDln    "Summation"
=Lpes    1            !Number of PEs
+Lpes    &Out
=Lcmp    "Divide"
=Lerf    "standard"
=Ltrn    "Linear"
=Llrn    "GRNN"
! Set up schedule
@NLRS    "grnnsum"
=lcta    99999
=ArrX    1
=lcft    "1.0 / tau"
?TimC    1.0
>bge    TimCOK
=TimC    1.0
:TimCOK
=lcfa    1.0
/lcfa    TimC
! Reset Factor
=ArrX    2
=lcft    "Reset Factor"
=lcfa    PrRs
@SLRS
=ArrX    0
=Llrs    "grnnsum"
=LInH    0.0
=LInL    0.0
+y    60            !up higher on display
@LDfW                !Default # weight fields
@LAdd

! Now do connections.
=cnwt    1.0
=cnty    WVar            !Variable
=cnsc    WRel            !Relative
=SPEl    LayN            !Summation Layer
@SlPE
=NPEl    n6            !Previous layer
@NrPE
@LCFl                !Full Connections

=n6    LayN            !summation layer

! Output layer
@LLdf                !start with default layer again
=LDln    "Out"            !layer name
=Lpes    &Out            !Number of PEs
=Ltrn    "Linear"
=Lerf    "standard"
=LInH    1.0
=LInL    1.0
+x    50
+y    60
@LAdd

! Fixed corresponding connections from Summation layer
! starting at second PE
=cnwt    1.0
=cnty    WFix            !Fixed
=cnsc    WRel            !Relative
!Destination layer:
=SPEl    LayN
=SPEn    0
!Source Layer
=NPEl    n6            !summation layer
=NPEn    1            !start at 2nd PE
:OutCn
@SlPE
@NrPE
@PCon                !connect two PEs together
+SPEn    1            !next PE in output layer
?SPEn    &Out            !past the end?
>bge    OutCnEnd
+NPEn    1            !next PE in the competitive layer
>br    OutCn

:OutCnEnd

=LnPr    0            !no pruning

!    *** Select Control Strategy & L/R Schedule ***

@LLsl                !load super layer

!
! I/O parameters:
!
=Llnn    "train"            !name of learn input
=Lrcn    "test"            !name of recall output
#Incl    "stdioset.iif"        !standard I/O settings
=Lax1    Epch            !set epoch from dialog
! Target ranges for MinMax tables
=Lscl    -1.0            !input  low-value
=Loff    1.0            !input  high-value
=Llow    0.0            !output low-value
=Lhgh    1.0            !output high-value

!    *** Load the Control Strategy and schedules ***
=Lctl    "grnn"
=GrLF    "grnn"            !Instrument List file
=Llio    1            !Ascii, sequential
@SVsl                !save it back
!
! Miscellaneous globals
=Grph     1            !Activate instrument list
=jogl    -.1            !lower limit for jog
=jogh    +.1            !upper limit for jog
=seed    257            !starting seed number
@seed                !set the seed
!
! Recall/Test modes
=RnTm    1
=RnRm    1
!set to learn one pass/all
=RnLm    1
!
!
! Initialize the network
!
@Nini
@EOF